User:Remig/plico/turn

Turn allows the user to make type I and II reverse turns and beta-hairpins in polypeptides with a single mouse click on the corner oxygen where you want the turn. ALT-CLICK creates a type I turn and SHIFT-CLICK makes a type II. Either on a proline N rotates the omega bond 180 for a cis/trans transition.

Turn is a member of the Plico suite of protein folding tools described here. It may be installed and accessed as a macro with the file:

Title=PLICO Turn
Script=script <path to your scripts folder>/turn.spt;plicoTurn

saved as plicoTurn.macro in your .jmol/macros folder as described in Macro.

A copy of the Plico script tug.spt must be in the same directory as this script.

Copy and paste the following to a text editor and save to your scripts directory as turn.spt:

#   turn - Jmol script by Ron Mignery
#
#   v1.2 beta    4/2/2014 for Jmol 14
#
#   Apply a type I or type II turn to a polypeptide
#

# Bound to ALT-LEFT-CLICK by plicoTurn
function turnCargo1MB() {

    # If O atom picked
    if ({atomIndex=_atomPicked}.atomName = "O") {
        gChain = {atomIndex=_atomPicked}.chain
        var cMidx = getScBBidx (_atomPicked, gChain)
        
        var caMidx = getNwardBBidx (cMidx, gChain)
        var nMidx = getNwardBBidx (caMidx, gChain)
        var ncMidx = getNwardBBidx (nMidx, gChain)
        var nPidx = getCwardBBidx (cMidx, gChain)
        var caPidx = getCwardBBidx (nPidx, gChain)
        var cPidx = getCwardBBidx (caPidx, gChain)
        var cnPidx = getCwardBBidx (cPidx, gChain)
        
        save state gState
        selectNwardIdx(caPidx, 0)
        setDihedralIdx(cnPidx, cPidx, caPidx, nPidx, 0) # cWard Psi
        selectNwardIdx(nPidx, 0)
        setDihedralIdx(cPidx, caPidx, nPidx, cMidx, -90) # cWard Phi
        selectNwardIdx(caMidx, 0)
        setDihedralIdx(nPidx, cMidx, caMidx, nMidx, -60) # nWard Psi
        selectNwardIdx(nMidx, 0)
        setDihedralIdx(cMidx, caMidx, nMidx, ncMidx, -40) # nWard Phi
        
        handleCollisions2( 0)
        if (countcollisions(({})) > 0) {
            var p = prompt("Unable to handle all collisions!")
            restore state gState
            connect
        }
    }

    # Else if PRO N atom picked
    if (({atomIndex=_atomPicked}.atomName = "N")
        and ({atomIndex=_atomPicked}.group = "PRO")) {
        gChain = {atomIndex=_atomPicked}.chain
        save state gState
        var cMidx = getNwardBBidx (_atomPicked, gChain)

        # Rotate 180 on omega        
        selectNwardIdx(cMidx, 0)
        rotateSelected {atomIndex=_atomPicked} {atomIndex=cMidx} 180.0

        handleCollisions2( 0)
        if (countcollisions(({})) > 0) {
            var p = prompt("Unable to handle all collisions!")
            restore state gState
            connect
        }
    }
}

# Bound to SHIFT-LEFT-CLICK by plicoTurn
function turnCargo2MB() {

    # If O atom picked
    if ({atomIndex=_atomPicked}.atomName = "O") {
        gChain = {atomIndex=_atomPicked}.chain
        var caMidx = getNwardBBidx (_atomPicked, gChain)
        var cMidx = getCwardBBidx (caMidx, gChain)
        
        save state gState
        var caMidx = getNwardBBidx (cMidx, gChain)
        var nMidx = getNwardBBidx (caMidx, gChain)
        var ncMidx = getNwardBBidx (nMidx, gChain)
        var nPidx = getCwardBBidx (cMidx, gChain)
        var caPidx = getCwardBBidx (nPidx, gChain)
        var cPidx = getCwardBBidx (caPidx, gChain)
        var cnPidx = getCwardBBidx (cPidx, gChain)
        
        # Hi to lo since N-terminal is to move
        selectNwardIdx(caPidx, 0)
        setDihedralIdx(cnPidx, cPidx, caPidx, nPidx, 0) # cWard Psi
        selectNwardIdx(nPidx, 0)
        setDihedralIdx(cPidx, caPidx, nPidx, cMidx, 90) # cWard Phi
        selectNwardIdx(caMidx, 0)
        setDihedralIdx(nPidx, cMidx, caMidx, nMidx, 120) # nWard Psi
        selectNwardIdx(nMidx, 0)
        setDihedralIdx(cMidx, caMidx, nMidx, ncMidx, -70) # nWard Phi

        handleCollisions2( 0)
        if (countcollisions(({})) > 0) {
            var p = prompt("Unable to handle all collisions!")
            restore state gState
            connect
        }
    }

    # Else if PRO N atom picked
    if (({atomIndex=_atomPicked}.atomName = "N")
        and ({atomIndex=_atomPicked}.group = "PRO")) {
        gChain = {atomIndex=_atomPicked}.chain
        save state gState
        var cMidx = getNwardBBidx (_atomPicked, gChain)

        # Rotate 180 on omega        
        selectNwardIdx(cMidx, 0)
        rotateSelected {atomIndex=_atomPicked} {atomIndex=cMidx} 180.0

        handleCollisions2( 0)
        if (countcollisions(({})) > 0) {
            var p = prompt("Unable to handle all collisions!")
            restore state gState
            connect
        }
    }
}

# Top level of Turn
function plicoTurn() {

    # Load common functions if not already
    if (kCommon < 1) {
        script $SCRIPT_PATH$tug.spt
        if (kCommon < 1) {
            prompt ("A newer version of plicoCommon.SPT is required")
            quit
        }
    }
    
    gPlico = "TURN"
    plicoPrelim()
    
    select (GLY and Oxygen) or (PRO and Nitrogen)
    halo on
    select all
    gEcho = ("_______TURN_______|  *** Click on O ***|      (or proline N)|ALT-CLICK=Type I" +
        "|SHIFT-CLICK=Type II|DOUBLE-CLICK=exit")
    echo @gEcho
    gChain = ""
    unbind

    bind "ALT-LEFT-CLICK" "_pickAtom";
    bind "ALT-LEFT-CLICK" "+:turnCargo1MB";
    bind "SHIFT-LEFT-CLICK" "_pickAtom";
    bind "SHIFT-LEFT-CLICK" "+:turnCargo2MB";
    bind "DOUBLE" "plicoExit";
}

# End of TURN.SPT

Contributors

Remig